Using the BUFFER-COPY method to assign data to/from a table whose fields have hyphens(-) in one buffer and underscores(_) in the other silently fails to copy the data to the corresponding fields in the target buffer.

This is a particularly common scenario in a DataServer environment, where the hyphens in source tables, fields and indexes are automatically translated to use the underscore character.

For example:

DEFINE TEMP-TABLE ttSource NO-UNDO
    FIELD field-name AS CHARACTER.

DEFINE TEMP-TABLE ttTarget NO-UNDO
    FIELD field_name AS CHARACTER.

CREATE ttSource.
ttSource.field-name = FILL("X",30).

CREATE ttTarget.
BUFFER ttTarget:BUFFER-COPY(BUFFER ttSource:HANDLE).

MESSAGE "Source: " ttSource.field-name SKIP 
        "Target: " ttTarget.field_name
    VIEW-AS ALERT-BOX INFORMATION BUTTONS OK.
    

Displays the following:

This is expected behavior.

This is not limited to underscores and hyphens, the default behavior of the BUFFER-COPY method is to find fields in the target that match the fields in the source and transfer data between them. 

If they are named differently the AVM ignores them and moves on to the next pair of matched fields.
 

Provide a field list for matching fields BUFFER-COPY method/statement  pairs-list option (3rd parameter).  This is a comma separated list of <sourcefield>,<targetfield>,<sourcefield>,<targetfield>.

The code below automates the dynamic building of a pairs list to be used with the buffer-copy method or statement.

DEFINE TEMP-TABLE ttSource NO-UNDO
    FIELD field-name AS CHARACTER.

DEFINE TEMP-TABLE ttTarget NO-UNDO
    FIELD field_name AS CHARACTER.

DEFINE VARIABLE cPairsList AS CHARACTER   NO-UNDO.
DEFINE VARIABLE cSource    AS CHARACTER   NO-UNDO.
DEFINE VARIABLE cTarget    AS CHARACTER   NO-UNDO.

DEFINE VARIABLE lHyphen    AS LOGICAL     NO-UNDO.

DEFINE VARIABLE iField     AS INTEGER     NO-UNDO.

DEFINE VARIABLE hSource    AS HANDLE      NO-UNDO.
DEFINE VARIABLE hTarget    AS HANDLE      NO-UNDO.
DEFINE VARIABLE hSrcCol    AS HANDLE      NO-UNDO.
DEFINE VARIABLE hTargCol   AS HANDLE      NO-UNDO.

ASSIGN hSource = BUFFER ttSource:HANDLE
       hTarget = BUFFER ttTarget:HANDLE.

/* Loop through the fields in the source buffer then search
   the target buffer for a field with the same name.  If not found
   in the target we check to see if there is a similarly named field
   with a hyphen or underscore one one side or the other */
   
DO iField = 1 TO hSource:NUM-FIELDS:
    ASSIGN hSrcCol = hSource:BUFFER-FIELD(iField)
           cSource = hSrcCol:NAME.
    
    /* Skip columns without the special characters */
    IF INDEX(cSource,"-") LT 1 AND 
       INDEX(cSource,"_") LT 1 THEN
        NEXT.
    
    /* Does it have a hyphen or an underscore? */
    lHyphen = (INDEX(cSource,"-") GT 0).

    hTargCol = hTarget:BUFFER-FIELD(cSource) NO-ERROR.
    /* If a match is found skip to next field, otherwise try
       to find a field with the opposite character in its name.  */
    IF ERROR-STATUS:NUM-MESSAGES GT 0 THEN 
        hTargCol = 
            hTarget:BUFFER-FIELD(IF lHyphen THEN 
                                     REPLACE(cSource,"-","_")
                                 ELSE REPLACE(cSource,"_","-")) NO-ERROR.
    ELSE NEXT.
    
    IF NOT VALID-HANDLE(hTargCol) THEN
        NEXT.
    
    cPairsList = cPairsList + 
                 (IF (cPairsList GT "") EQ TRUE THEN "," ELSE "") +
                 cSource + "," + hTargCol:NAME.
END.

CREATE ttSource.
ttSource.field-name = FILL("X",30).

CREATE ttTarget.
BUFFER ttTarget:BUFFER-COPY(BUFFER ttSource:HANDLE,?,cPairsList).

MESSAGE "Source: " ttSource.field-name SKIP 
        "Target: " ttTarget.field_name
    VIEW-AS ALERT-BOX INFORMATION BUTTONS OK.
    

The above code displays the following message: